Gradle’s camel-case support to abbreviate long task names on the command line is very efficient to work with. For example, if you have a task called processTestResources, you can run it like this:

$ gradle pTR

Nevertheless, task auto-completion on the command-line would be very nice to have, too. The following task definition generates a Bash auto-completion file for all tasks available in the current Gradle project. The Bash script itself has been taken from the Gradle cookbook.

class AutoCompletion extends DefaultTask {
    def includedTasks = project.tasks.all
    def File outputFile = project.file("${project.name}")

    def template = """
#!/bin/bash

_gradle_complete()
{
  local cur tasks

  COMPREPLY=()
  cur=\${COMP_WORDS[COMP_CWORD]}
  tasks='@@TASKS@@'
  cur=`echo \$cur | sed 's/\\\\\\\\//g'`
  COMPREPLY=(\$(compgen -W " \${tasks}" \${cur} | sed 's/\\\\\\\\//g') )
}

complete -F _gradle_complete -o filenames gradle
 """

    @TaskAction
    void generateFile() {
        String joinedTasks = includedTasks*.name.join(' ')
        String result = template.substring(1).replace('@@TASKS@@', joinedTasks)
        outputFile.write result
        logger.info "Successfuly generated Bash auto-completion file $outputFile.name. " +
                "Sudo copy $outputFile.name to /etc/bash_completion.d and call source /etc/bash_completion.d/$outputFile.name."
    }
}

We can now declare an AutoCompletion task in our Gradle build script. For example, in the following build script, we declare to generate the Bash auto-completion file without the tasks that are only relevant in a multi-project context. We also declare a different file name.

task autoCompletion(type: AutoCompletion) {
    includedTasks = tasks.all - tasks.findByPath(':buildDependents') - tasks.findByPath('buildNeeded')
    outputFile = file("${project.name}_ac")
}

Finally, we can run the autoCompletion task declared above.

$ gradle aC

Once we have the Bash auto-completion file, we just need to sudo copy it to /etc/bash_completion.d and call source on it.